***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Jan 19, 2019                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt TS360ILS-AU DC+ AC1 AC2 DC-
.param
+vc0 = 1.903e-7 		vc1 = 1.599e-8		vc2 = 1.85e-9		vc3 = 9.00e-2
+tc1 = 1.230e-1		tc2 = 4.720e-2					
g12 DC+ AC1 value={(vc0+vc1*v(DC+,AC1)+vc2*v(DC+,AC1)*v(DC+,AC1))*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))}
d12 AC1 DC+ diode
g13 DC+ AC2 value={(vc0+vc1*v(DC+,AC2)+vc2*v(DC+,AC2)*v(DC+,AC2))*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))}
d13 AC2 DC+ diode
g24 AC1 DC- value={(vc0+vc1*v(AC1,DC-)+vc2*v(AC1,DC-)*v(AC1,DC-))*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))}
d24 DC- AC1 diode
g34 AC2 DC- value={(vc0+vc1*v(AC2,DC-)+vc2*v(AC2,DC-)*v(AC2,DC-))*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))}
d34 DC- AC2 diode
.model diode d
***** flag parameter ***
+level = 1                     
***** dc model parameter ***
+ is = 1.030e-7		   n = 1.016		  rs = 4.501e-2		 ikf = 0.9
+ibv = 0.5e-3		 nbv = 1			  bv = 66
***** capacitance parameter ***
+cjo = 4.768e-10		   m = 4.555e-1		  vj = 5.617e-1
+ fc = 0.5
***** temperature coefficient ***
+tnom = 25			  eg = 0.710		 xti = 3
+trs1 = 3.8e-3		trs2 = -1.8e-5		tikf = -5.5e-3			
.ends TS360ILS-AU
*$
